ballerina/lang.stream

function 'map(stream<any|error, error|()> stm,  function(any|error) returns (any|error) func) returns stream<any|error, error|()>

Applies a function to each member of a stream and returns a stream of the results.

stream<float> ms = [14.5f, 45.5f, 6.8f, 4f].toStream();
stream<float> cms = ms.map(m => m * 100.0);
cms.next() ⇒ {"value":1450.0}

function close(stream<any|error, error|()> stm) returns error|()?

Closes a stream.

This releases any system resources being used by the stream. Closing a stream that has already been closed has no effect and returns ().

stream<int, error?> strm = new;
check strm.close();

function filter(stream<any|error, error|()> stm,  function(any|error) returns (boolean) func) returns stream<any|error, error|()>

Selects the members from a stream for which a function returns true.

stream<int> scores = [45, 60, 75, 30, 90].toStream();
scores.filter(score => score > 50).next() ⇒ {"value":60}

function forEach(stream<any|error, error|()> stm,  function(any|error) returns (() ) func) returns error|()

Applies a function to each member of a stream.

The parameter func is applied to each member of parameter stm stream in order.

stream<int> scores = [45, 60, 75, 30, 90].toStream();
int total = 0;
scores.forEach(function(int score) {
    total += score;
});
total ⇒ 300

function iterator(stream<any|error, error|()> stm) returns object {
    public isolated function next() returns record {|
        Type value;
    |}|CompletionType;
}

Returns an iterator over a stream.

stream<int> scores = [45, 60, 75, 30, 90].toStream();
object {
    public isolated function next() returns record {|int value;|}?;
} iterator = scores.iterator();
iterator.next() ⇒ {"value":45}

function next(stream<any|error, error|()> stm) returns record {| value any|error |}|error|()

Returns the next element in the stream wrapped in a record or () if the stream ends.

stream<int> scores = [45, 60, 75, 30, 90].toStream();
scores.next() ⇒ {"value":45}

function reduce(stream<any|error, ErrorType?> stm,  function(any|error, any|error) returns (any|error) func, any|error initial) returns any|error|ErrorType

Combines the members of a stream using a combining function.

The combining function takes the combined value so far and a member of the stream, and returns a new combined value.

stream<int> scores = [45, 60, 75, 30, 90].toStream();
scores.reduce(isolated function (int total, int score) returns int => total + score, 0) ⇒ 300