ballerina/lang.transaction

function getData() returns readonly

Retrieves data associated with the current transaction branch.

The data is set using setData.

function createEntity() returns error? {
    transaction {
        transaction:setData({accessType: "RO"});
        transaction:getData() ⇒ {"accessType":"RO"}
        check commit;
    }
}
transactional function updateDB() {
    transaction:setData({accessType: "RO"});
    transaction:getData() ⇒ {"accessType":"RO"}
}

function getInfo(byte[] xid) returns Info?

Returns information about the transaction with the specified xid.

byte[] xid = [48, 53, 101, 102, 101, 55];
transaction:getInfo(xid) ⇒ {"xid":[48, 53, 101, 102, 101, 55],"retryNumber":0,"prevAttempt":null,"startTime":2022-12-20 16:03:37,228}

function getRollbackOnly() returns boolean

Tells whether it is known that the transaction will be rolled back.

function createEntity() returns error? {
    transaction {
        transaction:setRollbackOnly(error("marked as rollback only"));
        transaction:getRollbackOnly() ⇒ true
        check commit;
    }
}
transactional function updateDB() {
    transaction:getRollbackOnly() ⇒ false
}

function info() returns Info

Returns information about the current transaction.

function createEntity() returns error? {
    transaction {
        transaction:Info info = transaction:info();
        check commit;
    }
}
transactional function updateDB() {
    transaction:Info info = transaction:info();
    info.xid ⇒ [100,102,53,51,97,57,57,51,45]
}

function onCommit(CommitHandler handler)

Adds a handler to be called if and when the global transaction commits.

function createEntity() returns error? {
    transaction {
        transaction:onCommit(onCommitHandle);
        check commit;
    }
}
transactional function updateDB() {
    transaction:onCommit(onCommitHandle);
}
isolated function onCommitHandle(transaction:Info info) {
    // Include the code to be executed when the transaction commits.
}

function onRollback(RollbackHandler handler)

Adds a handler to be called if and when the global transaction rolls back.

function createEntity() returns error? {
    transaction {
        transaction:onRollback(onRollBackHandle);
        check commit;
    }
}
transactional function updateDB() {
    transaction:onRollback(onRollBackHandle);
}
isolated function onRollBackHandle(transaction:Info info, error? cause, boolean willRetry) {
    // Include the code to be executed when the transaction rollback.
}

function setData(readonly data)

Associates some data with the current transaction branch.

function createEntity() returns error? {
    transaction {
        transaction:setData({accessType: "RO"});
        check commit;
    }
}
transactional function updateDB() {
    transaction:setData({accessType: "RO"});
}

function setRollbackOnly(error? e)

Prevents the global transaction from committing successfully.

This ask the transaction manager that when it makes the decision whether to commit or rollback, it should decide to rollback.

function createEntity() returns error? {
    transaction {
        transaction:setRollbackOnly(error("marked as rollback only"));
        check commit;
    }
}
transactional function updateDB() {
    transaction:setRollbackOnly(error("marked as rollback only"));
}